Petitverse

元三角関数不要論者にかかれば円を描くのに三角関数など不要

解法1:伝家の宝刀†フックの法則†を使わせて頂きますぞ！www

ACLS
XSCREEN 1

VAR K#=PI()*PI()*4/1024/1024 '円周を1024分割
VAR X#=320,VX#=0,X0#=200 'X座標,X速度,中心X
VAR Y#=120,VY#=PI()*2*120/1024,Y0#=120 'Y座標,Y速度,中心Y
VAR XP#=X#,YP#=Y# '過去の座標

VAR I%
FOR I%=1 TO 1024
　XP#=X#:YP#=Y#
　VX#=VX#-(X#-X0#)*K#
　VY#=VY#-(Y#-Y0#)*K#
　X#=X#+VX#:Y#=Y#+VY#
　
　GLINE ROUND(X#),ROUND(Y#),ROUND(XP#),ROUND(YP#)
NEXT I%
WAIT 1E5

解法2:回転,拡大,縮小を司りし代数、それは複素数
ACLS
XSCREEN 1

VAR R#=1000,J#=1
VAR X#=320,Y#=120 '半径120の円
VAR X0#=200,Y0#=120
VAR DIST#=SQR(R#*R#+J#*J#)
VAR XP#,YP#=120
R#=R#/DIST#:J#=J#/DIST#

WHILE Y#<120||YP#>=120
　XP#=X#:YP#=Y#
　VAR TMP#=X#
　X#=X0#+(TMP#-X0#)*R#-(Y#-Y0#)*J#
　Y#=Y0#+(TMP#-X0#)*J#+(Y#-Y0#)*R#
　GLINE ROUND(X#),ROUND(Y#),ROUND(XP#),ROUND(YP#)
WEND
WAIT 1E5


解法3:半径は別に0でも問題ないよね

ACLS
XSCREEN 1
GPSET 200,120
WAIT 1E5

解法4:ブレゼンハムって実は書いたことないのでこの機会に書いてみる

ACLS
XSCREEN 1

VAR X%=0,Y%=120
VAR XD%=0,YD%=119

WHILE X%<Y%
　GPSET 200+X%,120+Y%:GPSET 200+X%,120-Y%
　GPSET 200-X%,120+Y%:GPSET 200-X%,120-Y%
　GPSET 200+Y%,120+X%:GPSET 200+Y%,120-X%
　GPSET 200-Y%,120+X%:GPSET 200-Y%,120-X%
　XD%=XD%+(X%<<1)+1
　IF XD%>YD% THEN
　　YD%=YD%+(Y%<<1)-1
　　Y%=Y%-1
　ENDIF
　X%=X%+1
WEND
WAIT 1E5

解法5:等速円運動を知っていますか？僕は知っています

ACLS
XSCREEN 1

VAR X#=0,Y#=120
VAR VX#=1,VY#=0
VAR CENT#=1/120.0 '向心力
VAR XP#,YP#
VAR I%

FOR I%=1 TO 754
　XP#=X#+200:YP#=Y#+120
　VAR DIST#=SQR(X#*X#+Y#*Y#)
　VX#=VX#-X#/DIST*CENT#
　VY#=VY#-Y#/DIST*CENT#
　X#=X#+VX#:Y#=Y#+VY#
　GLINE ROUND(X#+200),ROUND(Y#+120),ROUND(XP#),ROUND(YP#)
NEXT I%
WAIT 1E5

解法6:誤差がなくて並列化にも向いてる素敵なアルゴリズム
ACLS
XSCREEN 1

VAR I%,J%

FOR I%=-120 TO 119
　FOR J%=-120 TO 119
　　IF SQR(I%*I%+J%*J%)<=120 THEN
　　　GPSET I%+200,J%+120
　　ENDIF
　NEXT J%
NEXT I%
WAIT 1E5

解法7:真円でなくてもいい←限度というものがある(高度サウンドユニット必須)

DIM X#[8192],Y#[8192],FP#[13]

VAR I%
FOR I%=0 TO 8191
　IF (I% DIV 256)AND 1 THEN
　　X#[I%]=80
　ELSE
　　X#[I%]=319
　ENDIF
　IF (I%+128)DIV 256 AND 1 THEN
　　Y#[I%]=0
　ELSE
　　Y#[I%]=239
　ENDIF
NEXT I%
BQPARAM FP#,1,8192,31,1
BIQUAD X#,X#,FP#
BIQUAD Y#,Y#,FP#
FOR I%=100 TO 611
　GLINE ROUND(X#[I%-1]),ROUND(Y#[I%-1]),ROUND(X#[I%]),ROUND(Y#[I%])
NEXT I%
WAIT 1E5

分かりやすくシンプルに済ませたいものです
(後で見たらこういちさんのと被ってました)

GCLS #C_CLEAR

X=150
Y=150

FOR II=0 TO 230
　FOR I=0 TO 400
　　IF (POW(X-1,2)+POW(Y-II,2) >= 2500) && (POW(X-1,2)+POW(Y-II,2) <= 2600) THEN GPSET I,II
　NEXT
NEXT

Jun_ さん
ネタ解法含めて7つも解法出しましたからね。どれかは被ってもおかしくないですね。ちょっと申しわけない。

過去の自分。単振動の挙動導出してたんだ…。(インターネッツで調べて諸々の定数計算してた)
そしてTypora持ってたんだ…(最近使った記憶がない)

さらなるカオス💀

1.
空のプログラムを実行する
OKと表示される。
OKのOが円形なのでクリアです。

2.
？"円"

3.
「自作プログラム」という指定がないため、GAHAKUを起動して円を描く
※フリーハンドで描いてください。
ツールの円を描く機能はGCIRCLEです。

4.「プチコンで」という指定がないため、
どうぶつの森のマイデザインなど、
他のゲームで円を描く。

5.Switchでという指定がないため、
うごメモで円を描く。

6.ゲームで、という指定がないため、
紙とペンを用意して円を描く。
コンパスを使うのがベスト。

7.世界のみんなで手をつないで輪をつくる。